8.逐像素光照

对于顶点数量较少的Sphere类型，可以很明显的看到光照范围边缘并不光滑，可以通过增加曲面细分等级或者改由片段着色器逐像素计算光照，这里采用第二种。

Shader "Custom/Phong_Pixel"
{
    Properties
    {
        _MainColor("MainColor",Color) = (1, 1, 1, 1)
        _Shininess("Shininess",Range(1,100)) = 1
        _SpecularColor("Specular Color",Color) = (0, 0, 0, 0)
    }
    SubShader
    {
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            #include "UnityLightingCommon.cginc"

            struct v2f
            {
                float4 pos : SV_POSITION;
                float3 normal : TEXCOORD0;
                float4 vertex : TEXCOORD1;
            };

            fixed4 _MainColor;
            fixed4 _SpecularColor;
            half _Shininess;

            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.normal = v.normal;
                o.vertex = v.vertex;              
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                 //法线向量 由模型空间变换到世界空间并标准化
                float3 n = UnityObjectToWorldNormal(i.normal);
                n = normalize(n);

                //灯光法向向量
                fixed3 l = normalize(_WorldSpaceLightPos0.xyz);
                
                //视线方向向量
                fixed3 view = normalize(WorldSpaceViewDir(i.vertex));

                //漫反射
                fixed ndotl = dot(n,l);
                fixed4 dif = _LightColor0 * _MainColor * saturate(ndotl);

                //镜面反射 光线方向取负，输入Reflect函数为光源到顶点的方向
                float3 ref = reflect(-l, n);
                ref = normalize(ref);
                fixed rdotv = saturate(dot(ref,view));
                fixed4 spec = _LightColor0 * _SpecularColor * pow(rdotv, _Shininess);

                //环境光 + 漫反射 +镜面反射
                return unity_AmbientSky + dif + spec;
            }
            ENDCG
        }
    }
}

光照计算交由frag进行，顶点着色器只负责传递发现和顶点（pos是裁切空间的顶点，vertex是模型空间的顶点用于计算方向向量），这里注意在frag里面texcoord语义可以用于存任意的float4类型，不局限于UV。

将原先编写的Shader改为逐像素渲染。

边缘明显清晰很多。